CoDrone LEDs

The easiest way to change your LEDs is to do it in void setup. This will change the LEDs’ colors and patterns before your program actually starts. There are thirteen(!) different combinations to set your color and patterns, and they all have this format:

setLED(Color, Mode, Interval)

OR

setLED(R, G, B, Mode, Interval)

Each LED function changes the LEDs on a different part of your CoDrone. These are your options:

• setEyeLED: changes the eyes’ LEDs
• setArmLED: changes the arms’ LEDs
• setAllLED: changes the eyes’ and arms’ LEDs
• setEyeDefaultLED: changes the eyes’ LEDs to the default
• setArmDefaultLED: changes the arms’ LEDs to the default
• setAllDefaultLED: changes the eyes’ and arms’ LEDs to the default
• resetDefaultLED: resets your CoDrone’s LEDs

Within the LED functions, there are a couple of ways to pick your color:

• You can type it in directly using names from this document.
• You can use RGB values to get a more precise color. RGB stands for red, green, and blue and all three can have values from 0 to 255. Any color values can be found on an RGB table like this one. Instead of typing in the color’s name, you can type in the three values that come up with commas in between.

You can have your LEDs just be solid, or you can have them make patterns! This is what your options for mode are:

• OFF: your LEDs are off
• SOLID: your LEDs are solid
• STROBE: your LEDs will flash a variety of colors
• BLINK: your LEDs will flicker at a steady rate
• DOUBLE_BLINK: your LEDs will flicker twice and then pause before repeating
• DIMMING: your LEDs will go from bright to dim and then back again
• PULSE: LEDs alternate between the front two arms and the back two arms
• REVERSE_PULSE: reverse of PULSE

Here are some examples of using LEDs in your CoDrone’s void setup code!

#include <CoDrone.h>

void setup() {
  CoDrone.begin(115200);
  CoDrone.pair();
  CoDrone.move(0.3);
  CoDrone.setArmLED(0, 255, 255, SOLID); //holds aqua color
}

void loop() {
}

#include <CoDrone.h>

void setup() {
  CoDrone.begin(115200);
  CoDrone.pair(); //connect to previously connected CoDrone
  CoDrone.move(0.3); //wait 0.3 seconds

  CoDrone.setArmLED(0, 255, 255, SOLID); //holds aqua color

  delay(100);
  
  CoDrone.setEyeLED(255, 0, 255, BLINK); //holds magenta color
}
 
void loop() {}

If you want to change the CoDrone’s LEDs more than once per program, there are a couple of ways to do that. One is with flags, so that your CoDrone’s LEDs will change whenever a flag is triggered. In this program, we also added buzzers so you have some idea of how your program is working.

#include<CoDrone.h>

int Flag;

void setup() {
  CoDrone.begin(115200);
  CoDrone.pair();
}

void loop() {
  byte bt1 = digitalRead(11);
  byte bt4 = digitalRead(14);
  byte bt8 = digitalRead(18);

  if (Flag == 0) {
    if (bt1) {
      Flag = 1;
      CoDrone.Buzz(4000, 8);
      delay(300);
      CoDrone.setArmLED(0, 255, 255, SOLID); //holds aqua color

    }
  } 
  else if (Flag == 1) {
    if (bt1) {
      Flag = 0;
      CoDrone.Buzz(8000, 8);
      delay(300);
      CoDrone.setArmLED(255, 255, 0, DIMMING); //dims yellow color

    }
  }
}

This is the pseudocode:

• Include the CoDrone library.
• Establish communication at a baud rate of 115200.
• Connect to a nearby drone.
• Establish sensors 11, 14, and 18 as inputs.
• If the flag is 0 and if sensor 11 is covered, set the flag to 1.
• Once the flag is at 1, play a sound on the buzzer, wait for 300 milliseconds, and set the CoDrone’s LEDs to dim aqua.
• Else, if the flag is at 1 and sensor 11 is covered, set the flag to 0.
• Once the flag is at 0, play a sound on the buzzer, wait for 300 milliseconds, and set the CoDrone’s LEDs to dim yellow.

You could technically include the LED commands in the flag if statements outside of the flag events in if(bt1), but then the LED commands will constantly be sending since they’re in void loop. If you include them within the flag events, the command will only need to be sent once and it will stay until another flag event is triggered.

Another way to change your CoDrone LEDs more than once per program is with timers. Again, this is easier to do with flags that trigger an event so you’re not sending the same commands over and over again.

#include <CoDrone.h>

unsigned long SetTime;
int ColorFlag;
void setup() {
  CoDrone.begin(115200);
  CoDrone.pair();
}

void loop() {
  if ( millis() - SetTime > 1000) {
    if (ColorFlag == 0) {
      CoDrone.setArmLED(255, 255, 255, DIMMING); //dims white color
      ColorFlag = 1;
    }
    else if (ColorFlag == 1) {
      CoDrone.setArmLED(255, 255, 0, DIMMING); //dims yellow color
      ColorFlag = 0;
    }

    SetTime = millis();
  }
}

You can use any of these methods in your CoDrone flight codes to make your programs more flashy. Here’s an example using an autonomous timer to change the flight movements and the LEDs.

#include <CoDrone.h>

unsigned long StartTime;
int StartFlag;

void setup() {
  CoDrone.begin(115200);
  CoDrone.pair();

  CoDrone.takeoff();
}

void loop() {
  byte bt1 = digitalRead(11);

  if (bt1) {
    StartFlag = 1;
    StartTime = millis();
  }

  if (StartFlag == 1) {
    if (millis() - StartTime < 1000) { 
      CoDrone.setEyeLED(255, 255, 255, DIMMING); //dims white color
      CoDrone.setThrottle(50);
      CoDrone.move();
    }
    else if ( millis() - StartTime < 3000) {
      CoDrone.setEyeLED(0, 0, 255, DIMMING); //dims blue color
      CoDrone.setPitch(50);  
      CoDrone.setThrottle(0);
      CoDrone.move();
    }
    else { 
      CoDrone.land();
      StartFlag = 0; 
    }
  }
}