While Loops

Loops let you repeat sections of your code. They’re a great shortcut — without them, you might have to write the same lines over and over again. You’ve already been using loops in your CoDrone programs — everything you use in void loop repeats!

In this lesson you’ll be learning about while loops, and in the next lesson, you’ll be learning about for loops. All of them are conditional loops, so they repeat only for as long the condition that you set is true.

While loops repeat a set of code while a certain condition you set is true. You use these in your life all of the time! For example: while it is raining, I will use an umbrella.

This is what while loops usually look like:

while(condition) {
    statement;
}

This is what all of that means:

• The condition is what needs to be true for the while loop to start.
• The statement is what will happen if the condition is true, and it will be checked every time the loop goes through.

If the condition is false, the program will exit the while loop.

So this is what the real-life example from above would look like in a while loop:

while(it is raining) {
    I will use an umbrella;
}

Upload this code to your remote and open your serial monitor to see what happens!

int x;

void setup() {
    Serial.begin(9600);
    delay(3000);
} 
void loop() {
    while (x < 3) {
        x = x + 1;
        Serial.println(x);
    }
    x = 0;
}

Bonus: try moving x = x + 1 outside of the while loop so your program looks like this:

int x;

void setup() {    
    Serial.begin(9600);    
    delay(3000);
}    

void loop() {        
    x = x + 1;    
        while (x < 3) {        
            Serial.println(x);    
        }    
    x = 0;
}

You can use your remote control’s sensors in your loops! However, because loops only read within the loop and the condition, this is where you should include the sensor update code.

There are two ways to do this:

1. You can store the variable inside the condition and explicitly tell the variable to update in the loop.

while (bt1){
    //Statement
    bt1 = digitalRead(11);
}

2. You can completely skip the variable and do a sensor check inside the condition.

while (digitalRead(11)){
    //Statement
}

There might be times when you don’t want your program to run until you send some type of start signal. One way to do this is with a flag, which you already learned about, but you can also use a while loop to pause your code and wait for input.

Upload this code to your remote control, open your serial monitor, and see what happens!

void setup() {
    Serial.begin(9600);
    pinMode(11, INPUT); 
    while (!digitalRead(11)) {
        Serial.println("Waiting...");
    }
}

void loop() {
    Serial.println("Started");
}

The pseudocode:

• Establish communication at a baud rate of 9600.
• Set up pin 11 as an input.
• While sensor 11 is not covered, print “Waiting…” in the serial monitor.
• When sensor 11 is covered, print “Started” in the serial monitor.

If you want to be able to pause your program so your CoDrone can hover, try this code! It uses sensor 17 in a while loop so that when it’s covered, the CoDrone will pause and hover in place. Pausing is great when you don’t want to crash into a moving object but also don’t want to completely stop your code.

#include <CoDrone.h>
int StartFlag;
unsigned long StartTime; 

void setup() { 
    CoDrone.begin(115200); 
    CoDrone.pair(); 
    
    CoDrone.takeoff();
} 

void loop() { 
    byte bt1 = digitalRead(11); 
    byte bt2 = digitalRead(12); 
    byte bt7 = digitalRead(17); 
    byte bt8 = digitalRead(18);  
    if (bt8) { 
        StartFlag = 1; 
        StartTime = millis(); 
    }  
    if (StartFlag == 1) { 
        if (millis() - StartTime < 2000) { 
            CoDrone.setThrottle(80);
            CoDrone.move(); 
        } 
        else if ( millis() - StartTime < 5000) { 
            CoDrone.setPitch(70); 
            CoDrone.setThrottle(0);
            CoDrone.move(); 
        } 
        else { 
            CoDrone.land(); 
            StartFlag = 0; 
        } 
    }  
    if ( bt1) { 
        StartFlag = 0; 
        CoDrone.emergencyStop(); 
    }  
    while (bt7) { 
        CoDrone.move(); 
        bt7 = digitalRead(17); 
    } 
}

While loops can also act like a switch since they’re kind of like a program within your program. This code works like a normal remote control code, but while sensor 18 is covered, it will also change your CoDrone’s LEDs!

#include <CoDrone.h>

void setup()
{
    CoDrone.begin(115200);
    CoDrone.pair(); 
    
    CoDrone.takeoff();
} 
void loop()
{
    byte bt1 = digitalRead(11);
    byte bt4 = digitalRead(14);
    byte bt8 = digitalRead(18);
    LEDs(0,0);
    if (bt1) {
        CoDrone.emergencyStop();
    } 
    if (PAIRING == true) {
        YAW = -1 * CoDrone.AnalogScaleChange(analogRead(22));
        THROTTLE = CoDrone.AnalogScaleChange(analogRead(23));
        ROLL = -1 * CoDrone.AnalogScaleChange(analogRead(24));
        PITCH = CoDrone.AnalogScaleChange(analogRead(25));
        CoDrone.move();
    } 
    while (bt8) {
        bt8 = digitalRead(18);
        LEDs(1,1);
        if (CoDrone.AnalogScaleChange(analogRead(22)) > 50) {
            CoDrone.setArmLED(255, 255, 0, DIMMING); //yellow
        }
        else if (CoDrone.AnalogScaleChange(analogRead(22)) < -50 ) {
            CoDrone.setArmLED(0, 0, 255, DIMMING); //blue
        }
    }
} 
void LEDs(int p13, int p16) {
    digitalWrite(13, p13);
    digitalWrite(16, p16);
}

Challenge:  While We’re At It…

Create an quick switch mode that uses your joysticks to set certain options while covering sensor 18.

Rules:

When sensor 18 is not covered:

• Normal remote control program.
• Sensor 11 should be a kill switch.

When sensor 18 is covered:

• The left joystick controls 4 different LED color modes. For example: Up makes arms yellow, Right makes arms blue, Down makes eyes green, Left makes eyes white.
• Limit the values for throttle, pitch, yaw, and roll from 0 to 100.

Bonus: include buzzers!